@ECHO OFF > NUL

REM	Batch file:  XSTEP-Edit.bat  
REM   http://wasp.cs.vu.nl/step/xstep/translation/XSTEP-Edit.bat
REM	Author:      Zhisheng Huang and Anton Eliens
REM	Revised:     10 April 2002
REM   Description: Launch XSTEP-Edit profile for XSTEP-compact using Xeena 1.2EA

REM -------------------------------------------------------------------------

REM ***	Edit the following directories as needed to match your installation.
REM ***	You will also need to edit the iconized XSTEP-Edit.lnk icon shortcut.

SET       XEENA_LOCATION=D:\Xeena

SET TRANSLATION_LOCATION=C:\xstep

SET              XSTEP_DTD=step

REM -------------------------------------------------------------------------

REM Delete 'REM' before your language of choice, or else
REM set XSTEPLanguagePreference as an environment variable
REM in your operating system (as described in README file).

REM	SET XSTEPLanguagePreference=German
REM	SET XSTEPLanguagePreference=French

REM -------------------------------------------------------------------------

REM ***	No further user editing needed after this point ***

SET EXAMPLES_DIR=%TRANSLATION_LOCATION%\examples

SET XSTEP_EDIT_DIR=%TRANSLATION_LOCATION%

SET XSTEP_EDIT_VERSION=0.20 using Xeena 1.2 EA and step.dtd

SET XSTEP_EDIT_SITE=http://wasp.cs.vu.nl/step/xstep/translation

SET READMEFILE=README.XSTEP-Edit.html

REM -------------------------------------------------------------------------

@ECHO XSTEP-Edit version %XSTEP_EDIT_VERSION%
@ECHO %XSTEP_EDIT_SITE%/%READMEFILE%

REM -------------------------------------------------------------------------

IF '%XSTEPLanguagePreference%'==''        GOTO EQUAL_BAR
IF '%XSTEPLanguagePreference%'=='English' GOTO EQUAL_BAR
SET XSTEPLanguagePreferenceProfile= -profile XSTEP-compact.profile%XSTEPLanguagePreference%
@ECHO Tooltips language:  %XSTEPLanguagePreference%

:EQUAL_BAR
@ECHO ====================================================================

IF EXIST                        %XSTEP_DTD%.dtd  GOTO ENVIRONMENT_OK
IF EXIST %TRANSLATION_LOCATION%\%XSTEP_DTD%.dtd  GOTO ENVIRONMENT_OK

@ECHO %XSTEP_DTD%.dtd not found - your machine might be out of environment space!!
exit

:ENVIRONMENT_OK

@copy %TRANSLATION_LOCATION%\%XSTEP_DTD%.profile  %TRANSLATION_LOCATION%\%XSTEP_DTD%.profile.save > NUL

REM Drag+Drop wraps filename in "quotes" so avoid doubly wrapped quoting & hanging

IF '%1'==''   GOTO NO_NAME
IF EXIST  %1  GOTO COMMAND_LINE
IF EXIST '%1' GOTO COMMAND_LINE
IF EXIST '%TRANSLATION_LOCATION%\%1' GOTO RELATIVE_NAME

GOTO NOT_FOUND

:RELATIVE_NAME
@ECHO Launch path\file specified on command line (or launch drag-and-drop)
@ECHO via relative path:  %TRANSLATION_LOCATION%\%1
@ECHO ====================================================================
@ECHO CLASSPATH= %CLASSPATH%
@ECHO ====================================================================
@ECHO ON
%XEENA_LOCATION%\xeena.bat  -dtd %TRANSLATION_LOCATION%\%XSTEP_DTD%.dtd  -root step  %XSTEPLanguagePreferenceProfile%  -xml %TRANSLATION_LOCATION%\%1
@GOTO DONE

:COMMAND_LINE
@ECHO Launch path\file specified on command line (or launch drag-and-drop):
@ECHO %1
@ECHO ====================================================================
@ECHO CLASSPATH= %CLASSPATH%
@ECHO ====================================================================
@ECHO ON
%XEENA_LOCATION%\xeena.bat  -dtd "%TRANSLATION_LOCATION%\%XSTEP_DTD%.dtd"  -root step  %XSTEPLanguagePreferenceProfile%  -xml %1
@GOTO DONE

:NOT_FOUND
@ECHO *** file %1 not found!

:NO_NAME
@ECHO Starting up XSTEP-Edit using read-only default file.
@ECHO ====================================================================
@ECHO CLASSPATH= %CLASSPATH%
@ECHO ====================================================================
@ECHO ON
%XEENA_LOCATION%\xeena.bat  -dtd "%TRANSLATION_LOCATION%\%XSTEP_DTD%.dtd"  -root step  %XSTEPLanguagePreferenceProfile%  -xml "step.xml"

:DONE