De slingervergelijking in Mathematica

Clear[vergelijking1, vergelijking2, oplossing1, oplossing2, constante, y, v];

We bekijken de "slingervergelijking" dy/dt = v, dv/dt = -sin y en de oplossingen daarvan voor twee verschillende begincondities:

vergelijking1 = {y'[t]==v[t], v'[t]==-Sin[y[t]], y[0]==1, v[0]==1};
oplossing1=NDSolve[vergelijking1,{y[t],v[t]}, {t,-4,4}];

vergelijking2 = {y'[t]==v[t], v'[t]==-Sin[y[t]], y[0]==1, v[0]==2};
oplossing2=NDSolve[vergelijking2,{y[t],v[t]}, {t,-4,4}];

De y-component van deze oplossingen ziet er, als functie van t, als volgt uit:

Plot[{y[t]/.oplossing1[[1]], y[t]/.oplossing2[[1]]},{t,-4,4}]

In het (y,v)-vlak (het "faseplaatje") is het kwalitatieve verschil tussen deze oplossingen nog beter zichtbaar:

ParametricPlot[{{y[t],v[t]}/.oplossing1, {y[t],v[t]}/.oplossing2} , {t,-4,4}]

Informatie over nog veel meer oplossingen is bevat in het richtingsveld van de slingervergelijking:

VectorPlot[{v, -Sin[y]},{y,-5,5}, {v,-4,4}]

En nog duidelijker is een faseplaatje waarin ook enkele banen zijn getekend:

StreamPlot[{v, -Sin[y]},{y,-5,5}, {v,-4,4}]

Een vergelijkbaar plaatje kan overigens worden verkregen door gebruik te maken van het feit dat de slingervergelijking een constante van beweging heeft (de "energie"):

constante[y_,v_]:=1/2 v^2 - Cos[y];
ContourPlot[constante[y,v],{y,-4,4},{v,-3,3}, Contours->20]