override protected function keyDownHandler(event:KeyboardEvent):void {
                          isKeyDown = true;
                          if (event.ctrlKey) {
                                  switch (event.keyCode) {
                                          case Keyboard.UP:
                                                  if (highlightedCell > -1) {
                                                          selectedIndex = highlightedCell;
                                                          dispatchEvent(new Event(Event.CHANGE));
                                                  }
                                                  close();
                                                  // Reset selectedIndex/prompt. Maybe dispatch change.
                                                  break;
                                          case  Keyboard.DOWN:
                                                  open();
                                                  break;
                                  }
                                  return;
                          }
                          
                          event.stopPropagation();
                          
                          var pageSize:int = Math.max((calculateAvailableHeight() / list.rowHeight)<<0, 1);
                          var sel:uint = selectedIndex;
                          var lastSel:Number = (highlightedCell == -1) ? selectedIndex : highlightedCell;
                          var newSel:int = -1;
                          switch (event.keyCode) {
                                  case Keyboard.SPACE:
                                          isOpen ? close() : open();
                                          return;
                                  case Keyboard.ESCAPE:
                                          if (isOpen) { 
                                                  if (highlightedCell > -1) {
                                                          selectedIndex = selectedIndex;
                                                  }
                                                  close();
                                          }
                                          return;
                                          
                                  case Keyboard.UP:
                                          newSel = Math.max(0, lastSel-1);
                                          break;
                                  case Keyboard.DOWN:
                                          newSel = Math.min(length-1, lastSel+1);
                                          break;
                                  case Keyboard.PAGE_UP:
                                          newSel = Math.max(lastSel - pageSize, 0);
                                          break;
                                  case Keyboard.PAGE_DOWN:
                                          newSel = Math.min(lastSel + pageSize, length - 1);
                                          break;
                                  case Keyboard.HOME:
                                          newSel = 0;
                                          break;
                                  case Keyboard.END:
                                          newSel = length-1;
                                          break;
                                          
                                  case Keyboard.ENTER:
                                          if (_editable && highlightedCell == -1) {
                                                  editableValue = inputField.text;
                                                  selectedIndex = -1;
                                          } else if (isOpen && highlightedCell > -1) {
                                                  editableValue = null;
                                                  selectedIndex = highlightedCell;
                                                  dispatchEvent(new Event(Event.CHANGE));
                                          }
                                          dispatchEvent(new ComponentEvent(ComponentEvent.ENTER));
                                          close();
                                          return;
                                          
                                  default:
                                          if (editable) { break; } // Don't allow letter keys to change focus when editable.
                                          newSel = list.getNextIndexAtLetter(String.fromCharCode(event.keyCode), lastSel);
                                          break;
                          }
                                                  
                          if (newSel > -1) {
                                  if (isOpen) {
                                          highlightCell(newSel);
                                          inputField.text = list.itemToLabel(getItemAt(newSel));
                                  } else {
                                          highlightCell();
                                          selectedIndex = newSel;
                                          dispatchEvent(new Event(Event.CHANGE));                                        
                                  }
                          }
                  }